[CMD] Как создать батник для обработки файлов определённого типа

[Melancholie]

задача такая: задается путь к файлам set "D=C:\Qt\pifagor\bin\repository\" и также есть батник для запуска одного файла с расширением .pfg:

set func_path=%func_name:.=\%

set repo_path=C:\Qt\pifagor\bin\

cd %repo_path%

cgen2 -f "%repo_path%repository\%func_path%\00.00\1.rig" "%repo_path%repository\%func_path%\00.00\1.cg%"

Надо сделать тоже самое, только чтобы не вводить название файла с расширением .pfg каждый раз, а взять все файлы с этим расширением из пути D, и запустить командой cgen2 -f
Как это сделать? Основная проблема в том, что я не знаю, как в цикле прописать изменяющиеся пути к файлам.

 

[Dragokas]

Здравствуйте!
Добро пожаловать на SafeZone!

батник для запуска одного файла с расширением .pfg:

не заметил там такого расширения. Вместо этого некий cg% с каким-то потерянным процентом.

а взять все файлы с этим расширением из пути D

Что такое путь D? (диск D?)

Рекурсивно? Или один уровень каталога?

 

[Melancholie]

Нет, D - это просто я так задала для удобства, чтобы ниже использовать. Вообще путь C:\Qt\pifagor\bin\repository\ Да, надо чтобы было рекурсивно.

 

[Dragokas]

set "func_path=%func_name:.=\%"

set repo_path=C:\Qt\pifagor\bin\repository

cd /d "%repo_path%"

for /f "delims=" %%a in ('dir /b /s /a-d "%repo_path%\*.pfg"') do cgen2 ...

И вместо ... подставляете нужные опции. Там, где нужно подставлять имя файла, пишите "%%a"
Если перед обработкой файла, требуется обязательный переход в папку, в которой он находится, пишите в строке с циклом (после do) cd /d "%%~dpa" & cgen2 ...

 

[Melancholie]

спасибо, мне очень помогло. Но вот еще нужна ваша помощь. работа все с тем же файлом. Надо выбрать все файлы в которых содержится в названии слово "test". Вот я вывожу их таким образом:

@Echo off

cd C:\Qt\pifagor\bin\

set func_path=%func_name:.=\%

set repo_path=C:\Qt\pifagor\bin\repository

cd /d %repo_path%

for /f "delims=" %%a in ('dir /b /s /a-d "%repo_path%\*.pfg"') do @findstr /m "test" %%a

Pause

правильно?
Есть команда inter2 , которая на вход принимает названия типа test.op.point (это просто пример введенного названия программы, то есть программы через точку, а на деле они выглядят как файл в файле, то есть test\op\point).
Мне надо, чтобы командой inter2 запускать не сами файлы, а программы, с подобным названием, лежащие в этих файлах.
То есть, в приведенном выше мною bat файле выводятся файлы типа

а мне надо как-то их обрезать, чтобы получилось так: test\op\point, а потом еще заменить \ на .

 

[Dragokas]

Попробуйте так:

@echo off

SetLocal EnableExtensions EnableDelayedExpansion

set "repo_path=C:\Qt\pifagor\bin\repository"

for /f "delims=" %%a in ('dir /b /s /a-d "%repo_path%\*.pfg" ^| find /i "\test\"') do (
  set "v=%%~dpna"
  set "v=!v:*\test\=test\!"
  set "v=!v:\=.!"
  echo !v!
)

pause

Предупреждение: в данном коде знаки ! в именах обрабатывать невозможно.

 

[Melancholie]

Да, так правильно, но надо, чтобы в конце названия 00.00.1 (то есть это стоит в конце названия) тоже не выводилось, а только test\op\numb например. как их убрать?

 

[Dragokas]

Как понять, по какому критерию их убирать? Кол-во символов? Кол-во слешей? ...

 

[Melancholie]

можно убрать по количеству слешей, то есть убрать 2 слеша с конца.

 

[Dragokas]

@echo off

SetLocal EnableExtensions EnableDelayedExpansion

set "repo_path=C:\Qt\pifagor\bin\repository"

for /f "delims=" %%a in ('dir /b /s /a-d "%repo_path%\*.pfg" ^| find /i "\test\"') do (
  set "v=%%~dpa"
  for %%c in ("!v:~0,-1!") do (
    set "v=%%~dpc"
    set "v=!v:~0,-1!"
    set "v=!v:*\test\=test\!"
    set "v=!v:\=.!"
    echo !v!
))
pause
goto :eof

 

[Melancholie]

здравствуйте, при попытке запуска этого выдается ошибка "Не удается инициализировать устройство PRN"

 

[Melancholie]

то есть у меня конечно выводятся нужные файлы, но и ошибка выводится.

а еще, подскажите, пожалуйста, куда мне мою команду inter для запуска с помощью нее такого рода файлов вписать?

от ошибки избавилась, но вопрос, куда мою команду записать, еще остался. заранее спасибо.

 

[Dragokas]

Вместо echo