Перекодировка текста (сборник кодов для различных кодовых страниц)

[Dragokas]

Привет!

Решил подсобрать коды перекодировки текстов родными средствами Windows + добавить пару новых фишек -)

Итак,

Спойлер: UTF-16 -> 866 (DOS)

chcp 866
cmd /d /a /c type utf16.txt > 866_out.txt

Спойлер: UTF16 -> 1251 (ANSI)

chcp 1251
cmd /d /a /c type utf16.txt > 1251_out.txt

Спойлер: UTF8 -> 1251

chcp 65001
cmd /d /u /c type utf8.txt > .tmp
chcp 1251
type .tmp > 1251_out.txt
del .tmp

Спойлер: 866 -> 1251

Если батник сохранять в кодировке 866

chcp 866
for %%? in ("") do chcp 1251 & cmd /d /a /c set /p=яю<NUL > .tmp
chcp 866
cmd /d /u /c type 866.txt >> .tmp
chcp 1251
cmd /d /a /c type .tmp > 1251_out.txt
del .tmp

Если батник сохранять в кодировке 1251

chcp 1251
cmd /d /a /c set /p=яю<NUL > .tmp
chcp 866
cmd /d /u /c type 866.txt >> .tmp
chcp 1251
cmd /d /a /c type .tmp > 1251_out.txt
del .tmp

Спойлер: 1251 -> 866

Если батник сохранять в кодировке 866

chcp 866
for %%? in ("") do chcp 1251 & cmd /d /a /c set /p=по<NUL > .tmp
cmd /d /u /c type 1251.txt >> .tmp
chcp 866
cmd /d /a /c type .tmp > 866_out.txt
del .tmp

Если батник сохранять в кодировке 1251

chcp 1251
cmd /d /a /c set /p=яю<NUL > .tmp
cmd /d /u /c type 1251.txt >> .tmp
chcp 866
cmd /d /a /c type .tmp > 866_out.txt
del .tmp

Спойлер: 866 -> UTF16 LE

Если батник сохранять в кодировке 866

chcp 866
chcp 1251 & cmd /d /a /c set /p=яю<NUL > utf16.txt
chcp 866 & cmd /d /u /c type 866.txt >> utf16.txt

Если батник сохранять в кодировке 1251

chcp 1251
cmd /d /a /c set /p=яю<NUL > utf16.txt
chcp 866 & cmd /d /u /c type 866.txt >> utf16.txt

Спойлер: 1251 -> UTF16 LE

Если батник сохранять в кодировке 866

chcp 866
chcp 1251 && cmd /d /a /c set /p=яю<NUL > utf16.txt
cmd /d /u /c type 1251.txt >> utf16.txt

Если батник сохранять в кодировке 1251

chcp 1251
cmd /d /a /c set /p=яю<NUL > utf16.txt
cmd /d /u /c type 1251.txt >> utf16.txt

Спойлер: Любая кодировка в любую

С использованием JScript-вставки

@set @x=0; /*
@echo off
call :Recode utf8.txt 1251_out.txt utf-8 windows-1251
pause
goto :eof

:Recode in.[исходный файл] in.[результирующий файл] in.[кодировка исходного файла] in.[кодировка результирующего файла]
  cscript.exe //nologo //e:jscript "%~f0" "%~1" "%~2" "%~3" "%~4"
Exit /B

*/with (new ActiveXObject('ADODB.Stream')) {
  Charset = WScript.Arguments(2);
  Open();
  LoadFromFile (WScript.Arguments(0));
  Text = ReadText();
  Close();
  Charset = WScript.Arguments(3);
  Open();
  WriteText (Text);
  SaveToFile (WScript.Arguments(1), 2);
  Close();
}

Названия доступных кодировок можно посмотреть в колонке .NET Name
в статье: https://msdn.microsoft.com/en-us/lib...(v=vs.85).aspx

С использованием внешних утилит:

win_iconv

Это программа с открытым исходным кодом.

Скачать утилиту.

Синтаксис:

iconv [-c] [-s] [-f encoding] [-t encoding] [inputfile …]

Перечень кодировок:

iconv -l

Пример использования:

win_iconv -f UTF-16LE -t cp866 "UTFtext.txt" > "DOStext.txt"

Подробности в этой теме.

Демо-набор есть в архиве. Также прилагаю Excel-файл с всеми кодами символов, в том числе китайскими -)
Спасибо за внимание. Надеюсь, окажется Вам полезным.

 

[Dragokas]

Примеры универсальных (насколько это возможно для пакетного файла) перекодировщиков от ComSpec.

Спойлер: OEM-866 -> Win-1251

@chcp 866>nul
@<"in.file">"out.file" (for /f "delims=" %%i in ('find/n /v ""') do @chcp 1251>nul& set x=%%i& cmd/v/c echo[!x:*]^^=!)

Спойлер: OEM-866 -> UTF-8

@chcp 866>nul
@<"in.file">"out.file" (for /f "delims=" %%i in ('find/n /v ""') do @chcp 65001>nul& set x=%%i& cmd/v/c echo[!x:*]^^=!)

Спойлер: Win-1251 -> OEM-866

@chcp 1251>nul
@<"in.file">"out.file" (for /f "delims=" %%i in ('find/n /v ""') do @chcp 866>nul& set x=%%i& cmd/v/c echo[!x:*]^^=!)

Спойлер: Win-1251 -> UTF-8

@chcp 1251>nul
@<"in.file">"out.file" (for /f "delims=" %%i in ('find/n /v ""') do @chcp 65001>nul& set x=%%i& cmd/v/c echo[!x:*]^^=!)

Спойлер: UTF-8 -> OEM-866

@chcp 65001>nul
@<"in.file">"out.file" (for /f "delims=" %%i in ('find/n /v ""') do @chcp 866>nul& set x=%%i& cmd/v/c echo[!x:*]^^=!)

Спойлер: UTF-8 -> Win-1251

@chcp 65001>nul
@<"in.file">"out.file" (for /f "delims=" %%i in ('find/n /v ""') do @chcp 1251>nul& set x=%%i& cmd/v/c echo[!x:*]^^=!)

Спойлер: UTF-16 -> OEM-866

:: Не зависит от какой-нибудь из трёх (866, 1251, 65001) кодовых страниц, продекларированной на момент исполнения кода.
@<"in.file">"out.file" (for /f "delims=" %%i in ('find/n /v ""') do @chcp 866>nul& set x=%%i& cmd/v/c echo[!x:*]^^=!)

Спойлер: UTF-16 -> Win-1251

:: Не зависит от какой-нибудь из трёх (866, 1251, 65001) кодовых страниц, продекларированной на момент исполнения кода.
@<"in.file">"out.file" (for /f "delims=" %%i in ('find/n /v ""') do @chcp 1251>nul& set x=%%i& cmd/v/c echo[!x:*]^^=!)

Спойлер: UTF-16 -> UTF-8

:: Не зависит от какой-нибудь из трёх (866, 1251, 65001) кодовых страниц, продекларированной на момент исполнения кода.
@<"in.file">"out.file" (for /f "delims=" %%i in ('find/n /v ""') do @chcp 65001>nul& set x=%%i& cmd/v/c echo[!x:*]^^=!)

В отличие от ранее предлагавшихся перекодировщиков, основанных на построчном разборе текста в цикле командой "for", данный код абсолютно устойчив к специальным символам, встречающимся в тексте, и полностью сохраняет форматирование текста, включая пустые строки. Код проверялся на всех символах английской и русской раскладки клавиатуры. Максимальная длина обрабатываемых строк может достигать 4091 символа.

Спойлер: WIN-1251 -> OEM-866 (из файла в переменную без временных файлов)

@echo off

>nul chcp 1251
<"example.txt" (for /f "delims=" %%i in ('more') do >nul chcp 866& set/a n+=1& call set x%%n%%=%%i)
set x

pause

Ни в коем случае нельзя chcp 1251 (т.е. весь вот этот код) помещать в блок скобок, если не включен режим отложенного раскрытия переменных.

 

[regist]

Спойлер: определение кодировки